ШАБЛОН БОЯ НА URQ
Главная

Автор: Belial

А нужен ли бой вообще?
Лично по моему мнению квест это в первую очередь квест, а не экшн, поэтому злоупотреблять в нем элементами боевых игр и RPG все таки не стоит. И все таки приправить кое где свое творение хорошей потассовкой можно, а если еще облачить бой в форму головоломки, то я обеими руками за. Предлагаемая мной боевая система может быть использована начинающими авторами в качестве шаблона или учебного пособия. Да и опытному автору квестов на URQ возможно пригодиться готовый кусок кода - в самом деле - зачем тратить время на то, что уже сделано кем-то и вполне отвечает вашим целям и требованиям.


Описание.
Система простая. Вы поочередно делаете ход за себя и за врага. Случайным образом определяется - достиг удар цели или нет, если достиг - опять же в случайном порядке определяется сила удара и соответственно количество потерянного здоровья. Состояние противников постоянно отображается в диалоговом окне. Возможно кому-то покажется нудным каждый раз жать на кнопку для нанесения удара, но лично меня ужасно раздражают боевые системы, просчитывающие весь бой без участия игрока (я такое видел и не раз). В шаблоне существует возможность выбора оружия - кулак(+0 к силе удара), кинжал (+5 ) и меч (+10). Перед каждым ударом вы можете выбрать оружие, которым нанесете удар.
Само собой в вашей воле изменить код так, как вам удобно, как вам больше нравиться, как больше подходит для вашего квеста. На мой взгляд шаблон достаточно универсален и с небольшими изменениями может подойти для любого квеста, где может понадобиться.


Как использовать. ( Для самых маленьких :)) )
Чтобы вставить код в свою игру достаточно просто скопировать его в свой код и в нужной локации поставить ссылку: btn Готовность№1, Атака!
Локацию Начало использовать не надо, только не забудте в начале своего кода прописать две основные переменные: жизнь=100 и instr orug=кулаком


Код.


:Начало
if not статус then inv+ статус
if not кулаки then inv+ 2, кулаки
if not кинжал then inv+ кинжал
if not меч then inv+ меч
if кряк=1 then убийства=0
жизнь=100
оружие=1
instr orug=кулаком
goto Готовность№1
end

:Готовность№1
кря=0
кряк=0
жизнь2=100
pln Шаблон боевой системы
pln #$
pln сделано Belial'ом
pln #$
pln belgame@bk.ru www.questtext.narod.ru
pln ---------------------
pln #$
pln Враг перед тобой. Ты готов к бою?
btn бой2, Готов!
if жизнь<90 then btn Начало, Погоди, надо зализать раны.
end

;------БОЙ------

:бой
pln Враг наносит удар.
proc случай
if рнд<0.5 then pln Ты ловко уклонился.
if рнд>0.5 or рнд=0.5 then pln Удар врага достиг
цели и отнял у тебя #рнд*10%$ жизни. & жизнь=жизнь-#рнд*10$
pln #жизнь2$ жизней осталось у врага
pln #жизнь$ жизней осталось у тебя
proc смерть
proc смерть3
if кряк=1 then cls & goto смерть2
btn бой2, Твой удар
end

:бой2
pln Ты дерешься #%orug$
pln #$
pln Ты наносишь удар.
proc случай
if рнд<0.5 then pln Враг парировал удар.
if рнд>0.5 or рнд=0.5 then pln Ты ударил #%orug$ и отнял
у врага #рнд*10+оружие$ жизней. &
жизнь2=жизнь2-#рнд*10+оружие$
pln #жизнь2$ жизней осталось у врага
pln #жизнь$ жизней осталось у тебя
proc смерть
proc смерть3
if кря=1 then cls & goto смерть4
btn бой, Удар врага
end

;--------СЛУЧАЙ---------

:случай
рнд =rnd
end

;----------СТАТУС----------
:Use_статус
pln ------------------
pln #жизнь$ жизней
pln #убийства$ убийства
end

;------СМЕРТЬ------

:смерть
if жизнь=0 or жизнь<0 then кряк=1
end

:смерть2
pln Кажись тебя того... & btn Начало, Сначала?
end

:смерть3
if жизнь2=0 or жизнь2<0 then кря=1
end

:смерть4
pln Твой враг повержен.
pln #$
убийства=убийства+1 & goto Готовность№1
end

;------ ИСПОЛЬЗОВАТЬ ОРУЖИЕ -----

:Use_кулаки_использовать
оружие=0
instr orug= кулаком
end

:Use_кинжал_использовать
оружие=3
instr orug= кинжалом
end

:Use_меч_использовать
оружие=10
instr orug= мечем
end

А здесь можно скачать файл .qst с этим шаблоном.

Квесты:
Движки
> Статьи <
Форум
Гостевая
Связь
Ссылки



Сайт управляется системой uCoz